表題

多重値を受け取る構文

著者

Lars T Hansen

状態

この SRFI は現在「確定」の状態である。 SRFI の各状態の説明についてはここを参照せよ。この SRFI に関する議論についてはメーリングリストのアーカイブを参照せよ。

受理: 1999/09/10
草案: 1999/09/14-1999/11/12
改訂: 1999/11/01
改訂: 2000/03/15
確定: 2000/03/15

概要

この SRFI では、多重値を返す式の値を束縛するための LET-VALUES および LET*-VALUES 構文フォームを導入する。

課題

なし。

論拠

LET-VALUES と LET*-VALUES は、多重値を受け取るための CALL-WITH-VALUES の記法の面倒さを軽減する。

仕様

(LET-VALUES ((<formals> <expression>) ...) <body>) 構文

<formals> は LAMBDA 式と同じような仮引数リストである。 R5RS のセクション 4.1.4 を参照せよ。

<expression> が現在の環境で評価され、 <formals> の変数が新しいロケーションに束縛され、 <expression> の戻り値がその変数に格納され、 <body> がその拡張された環境で評価され、 <body> の最後の式の値が返される。 <body> は <tail body> である (R5RS のセクション 3.5 を参照せよ) 。

<formals> と値のマッチングは、LAMBDA 式の引数のマッチングと同様である。 <expression> が対応する <formals> にマッチしない個数の値を返すことはエラーである。

             (let-values (((a b . c) (values 1 2 3 4)))
               (list a b c))            --> (1 2 (3 4))

             (let ((a 'a) (b 'b) (x 'x) (y 'y))
               (let-values (((a b) (values x y))
                            ((x y) (values a b)))
                 (list a b x y)))       --> (x y a b)

(LET*-VALUES ((<formals> <expression>) ...) <body>) 構文

<formals> は LAMBDA 式と同じような仮引数リストである。 R5RS のセクション 4.1.4 を参照せよ。

LET*-VALUES は LET-VALUES に類似しているが、束縛は左から右に順番に行われ、 (<formals> <expression>) で示される束縛が有効な範囲は、その束縛の右側にあるすべての LET*-VALUES の部分式に及ぶ。したがって、2 つめの束縛は最初の束縛が有効となっている環境内で行われ、 3 つめ以降の束縛も同様に前の束縛の環境内で行われる。

             (let ((a 'a) (b 'b) (x 'x) (y 'y))
               (let*-values (((a b) (values x y))
                             ((x y) (values a b)))
                 (list a b x y)))       --> (x y x y)

実装

以下の実装は R5RS Scheme で書かれているが、IEEE Scheme 標準とは互換性がない。 IEEE 標準では高レベルのマクロシステムをサポートしていないからである。

この実装では、R5RS により定義されているトップレベルの名前は元の値に束縛されていることを仮定している。

;; This code is in the public domain.

(define-syntax let-values
  (syntax-rules ()
    ((let-values (?binding ...) ?body0 ?body1 ...)
     (let-values "bind" (?binding ...) () (begin ?body0 ?body1 ...)))

    ((let-values "bind" () ?tmps ?body)
     (let ?tmps ?body))

    ((let-values "bind" ((?b0 ?e0) ?binding ...) ?tmps ?body)
     (let-values "mktmp" ?b0 ?e0 () (?binding ...) ?tmps ?body))

    ((let-values "mktmp" () ?e0 ?args ?bindings ?tmps ?body)
     (call-with-values
       (lambda () ?e0)
       (lambda ?args
         (let-values "bind" ?bindings ?tmps ?body))))

    ((let-values "mktmp" (?a . ?b) ?e0 (?arg ...) ?bindings (?tmp ...) ?body)
     (let-values "mktmp" ?b ?e0 (?arg ... x) ?bindings (?tmp ... (?a x)) ?body))

    ((let-values "mktmp" ?a ?e0 (?arg ...) ?bindings (?tmp ...) ?body)
     (call-with-values
       (lambda () ?e0)
       (lambda (?arg ... . x)
         (let-values "bind" ?bindings (?tmp ... (?a x)) ?body))))))

(define-syntax let*-values
  (syntax-rules ()
    ((let*-values () ?body0 ?body1 ...)
     (begin ?body0 ?body1 ...))

    ((let*-values (?binding0 ?binding1 ...) ?body0 ?body1 ...)
     (let-values (?binding0)
       (let*-values (?binding1 ...) ?body0 ?body1 ...)))))

著作権

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

編集者: Mike Sperber

最終更新日時: Sun Jan 28 13:40:20 MET 2007