表題

可変個引数の手続きの構文

著者

Lars T Hansen

状態

この SRFI は「確定」の状態にある。 SRFI の各状態の説明についてはここを参照せよ。この SRFI に関する議論についてはメーリングリストのアーカイブを参照せよ。

受理: 1999/11/01
草案: 1999/11/06-2000/01/07
確定: 2000/03/10

概要

可変個引数の手続きのための CASE-LAMBDA 構文を導入する。

論拠

CASE-LAMBDA は渡された引数の個数によって異なるコードを実行するような手続きの煩雑さを軽減する。これは引数の個数に対するパターンマッチングの仕組みを提供する。 CASE-LAMBDA はすでにいくつかの Scheme システムに用意されている。

CASE-LAMBDA は R5RS Scheme で定義されている機能のみを使用したマクロで実装できるが、処理系固有の最適化を行ってもよい。

仕様

(CASE-LAMBDA <clause> ...) 構文

各 <clause> は (<formals> <body>) の形式とする。ここで <formals> は LAMBDA に対する仮引数のリストである (R5RS の section 4.1.4 参照)。各 <body> は <末尾本体> である (R5RS の section 3.5 参照)。

CASE-LAMBDA 式を評価すると、可変個の引数を受け取る手続きが生成される。この手続きは、LAMBDA 式で手続きを定義した場合と同じレキシカルスコープに位置する。この手続きに引数 V1 .. Vk を指定して呼び出した場合、その引数が <formals> に一致する最初の <clause> が選択される。引数が一致するかどうかは LAMBDA 式の <formals> に一致する仕様と同じとする。 <formals> の変数は新しいロケーションに束縛され、値 V1 .. Vk がそのロケーションに格納される。この拡張された環境において <body> が評価され、 <body> の結果が手続き呼び出しの戻り値として返される。

引数の個数がいずれの <clause> の <formals> にも一致しない場合は、エラーである。

             (define plus
               (case-lambda
                 (() 0)
                 ((x) x)
                 ((x y) (+ x y))
                 ((x y z) (+ (+ x y) z))
                 (args (apply + args))))

             (plus)                     --> 0
             (plus 1)                   --> 1
             (plus 1 2 3)               --> 6

             ((case-lambda
               ((a) a)
               ((a b) (* a b)))
              1 2 3)                    --> error

実装

R5RS Scheme による実装を以下に示す。この実装は IEEE Scheme 標準規格とは互換性がない。 IEEE 標準規格には高レベルのマクロシステムがないからである。

この実装では、 R5RS で定義されているいくつかのトップレベルの名前が、オリジナルの値に束縛されていることを仮定している。

;; このコードはパブリック ドメインとする。

(define-syntax case-lambda
  (syntax-rules ()
    ((case-lambda
      (?a1 ?e1 ...)
      ?clause1 ...)
     (lambda args
       (let ((l (length args)))
         (case-lambda "CLAUSE" args l
           (?a1 ?e1 ...)
           ?clause1 ...))))
    ((case-lambda "CLAUSE" ?args ?l
      ((?a1 ...) ?e1 ...)
      ?clause1 ...)
     (if (= ?l (length '(?a1 ...)))
         (apply (lambda (?a1 ...) ?e1 ...) ?args)
         (case-lambda "CLAUSE" ?args ?l
           ?clause1 ...)))
    ((case-lambda "CLAUSE" ?args ?l
      ((?a1 . ?ar) ?e1 ...)
      ?clause1 ...)
     (case-lambda "IMPROPER" ?args ?l 1 (?a1 . ?ar) (?ar ?e1 ...)
       ?clause1 ...))
    ((case-lambda "CLAUSE" ?args ?l
      (?a1 ?e1 ...)
      ?clause1 ...)
     (let ((?a1 ?args))
       ?e1 ...))
    ((case-lambda "CLAUSE" ?args ?l)
     (error "Wrong number of arguments to CASE-LAMBDA."))
    ((case-lambda "IMPROPER" ?args ?l ?k ?al ((?a1 . ?ar) ?e1 ...)
      ?clause1 ...)
     (case-lambda "IMPROPER" ?args ?l (+ ?k 1) ?al (?ar ?e1 ...)
      ?clause1 ...))
    ((case-lambda "IMPROPER" ?args ?l ?k ?al (?ar ?e1 ...)
      ?clause1 ...)
     (if (>= ?l ?k)
         (apply (lambda ?al ?e1 ...) ?args)
         (case-lambda "CLAUSE" ?args ?l
           ?clause1 ...)))))

著作権

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

編集者: Mike Sperber

最終更新日時: Mon Apr 19 20:38:48 CEST 2004