表題

基本的な書式文字列

著者

Scott G. Miller

状態

この SRFI は現在「確定」の状態である。 SRFI の各状態の説明についてはここを参照せよ。この SRFI に関する議論についてはメーリングリストのアーカイブを参照せよ。

草案: 2002/03/23-2002/05/23
確定: 2002/06/25

概要

この SRFI では、書式文字列 (format string) の仕様を定義する。書式文字列とは、エスケープシーケンス (escape sequence) を含む Scheme 文字列のことである。エスケープシーケンスは、その意味論に従って別の文字列に置換される。

論拠

多くの Scheme 処理系には format と呼ばれる関数がある。この関数は、引数として書式文字列 (0 個以上のエスケープシーケンスを含む普通の Scheme 文字列) と 0 個以上の Scheme オブジェクトを受け取り、規則に従って書式文字列中のエスケープシーケンスを置換する。この SRFI では、format 関数の基本的な機能を定義し、 Scheme 実装者にあまり負担をかけずに、この関数を使用して移植性の高いコードを書けるようにする。

仕様

format format-string [obj ...] -> string

メッセージテンプレート (Scheme 文字列) を受け取り、その中のエスケープシーケンスを順に別の文字列に置換する。どのような文字列に置換されるかは、エスケープシーケンスの意味論により決定される。

エスケープシーケンスは 2 文字のシーケンスで、最初の文字はチルダ '~' である。エスケープコードの意味は次のとおり。

~a 対応する値を display で表示したときの値に置換される。

~s 対応する値を write で表示したときの値に置換される。

~% 改行 (newline) に置換される。

~~ チルダ '~' に置換される。

~a や ~s を使用した場合は、対応する Scheme 値を format の引数として渡さなければならない。引数に渡される値の順序は、書式文字列中のエスケープシーケンスの順序に対応する。エスケープシーケンスに対応する値が存在しない場合は、エラーである。

~% と ~~ は対応する値を必要としない。

使用例

(format "Hello, ~a" "World!")
; => "Hello, World!"

(format "Error, list is too short: ~s~%" '(one "two" 3))
; => "Error, list is too short: (one \"two\" 3))"

実装

以下の実装では、 SRFI-6 (基本的な文字列ポート) と SRFI-23 (エラー報告機構) を使用している。

(define format
  (lambda (format-string . objects)
    (let ((buffer (open-output-string)))
      (let loop ((format-list (string->list format-string))
                 (objects objects))
        (cond ((null? format-list) (get-output-string buffer))
              ((char=? (car format-list) #\~)
               (if (null? (cdr format-list))
                   (error 'format "Incomplete escape sequence")
                   (case (cadr format-list)
                     ((#\a)
                      (if (null? objects)
                          (error 'format "No value for escape sequence")
                          (begin
                            (display (car objects) buffer)
                            (loop (cddr format-list) (cdr objects)))))
	             ((#\s)
                      (if (null? objects)
                          (error 'format "No value for escape sequence")
                          (begin
                            (write (car objects) buffer)
                            (loop (cddr format-list) (cdr objects)))))
                     ((#\%)
                      (newline buffer)
                      (loop (cddr format-list) objects))
                     ((#\~)
                      (write-char #\~ buffer)
                      (loop (cddr format-list) objects))
                     (else
                      (error 'format "Unrecognized escape sequence")))))
              (else (write-char (car format-list) buffer)
                    (loop (cdr format-list) objects)))))))

著作権

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

編集者: Francisco Solsona

著者: Scott G. Miller

最終更新日時: Mon Apr 8 06:54:37 CDT 2002